PCSC Support (updated PCSC-Lite, CCID)

These are the recipes which build the latest pcsc-lite, ccid lib, acsccid lib.

pcsc-lite_1.8.8.bb

DESCRIPTION = "PC/SC Lite smart card framework and applications"
HOMEPAGE = "http://pcsclite.alioth.debian.org/"
LICENSE = "BSD"
LIC_FILES_CHKSUM = "file://COPYING;md5=a39d325b7d9cf2f07826a5154b16500c"
DEPENDS = "libusb1"
RDEPENDS = "libusb1"
RRECOMMENDS_${PN} = "ccid"

PACKAGES =+ "${PN}-lib"
PR = "r3"

SRC_URI = "https://alioth.debian.org/frs/download.php/file/3862/pcsc-lite-${PV}.tar.bz2 \
	file://pcscd.init"

SRC_URI[md5sum] = "069dc875a2ae2d85a2ebceac73252c0a"
SRC_URI[sha256sum] = "fe66354a7e738d3ef8b4e572c7e447b85894da9262381fbf004e8abcc12885e7"

inherit autotools update-rc.d

INITSCRIPT_NAME = "pcscd"
INITSCRIPT_PARAMS = "defaults"

EXTRA_OECONF = " \
	--disable-libudev \
	--enable-libusb \
	--enable-embedded \
	--enable-usbdropdir=${libdir}/pcsc/drivers \
	"

do_install() {
	oe_runmake DESTDIR="${D}" install
	install -d "${D}/etc/init.d"
	install -m 755 "${WORKDIR}/pcscd.init" "${D}/etc/init.d/pcscd"
}

do_patch() {
	sed -i 's/2.69/2.68/' ${S}/configure.ac
}

S = "${WORKDIR}/pcsc-lite-${PV}"

FILES_${PN}-lib = "${libdir}/lib*${SOLIBS}"

ccid_1.4.11.bb

DESCRIPTION = "Generic USB CCID smart card reader driver"
HOMEPAGE = "http://pcsclite.alioth.debian.org/ccid.html"
LICENSE = "LGPLv2.1+"
LIC_FILES_CHKSUM = "file://COPYING;md5=2d5025d4aa3495befef8f17206a5b0a1"
PR = "r1"

DEPENDS = "virtual/libusb0 pcsc-lite"
RDEPENDS_${PN} = "pcsc-lite"

SRC_URI = "https://alioth.debian.org/frs/download.php/file/3920/ccid-${PV}.tar.bz2"

SRC_URI[md5sum] = "20e3d6f045c53707a597cbacb86b6c5b"
SRC_URI[sha256sum] = "04ce7ebc7f591b7542e15d4dcd1c50900d0d86c0639893832f5d6144ffb3c369"

inherit autotools

do_patch() {
	sed -i 's/2.69/2.68/' ${S}/configure.ac
}

FILES_${PN} += "${libdir}/pcsc/"
FILES_${PN}-dbg += "${libdir}/pcsc/drivers/*/*/*/.debug"

acsccid_1.0.4.bb

DESCRIPTION = "ACS USB CCID smart card reader driver"
HOMEPAGE = "http://sourceforge.net/projects/acsccid"
LICENSE = "LGPLv2.1+"
LIC_FILES_CHKSUM = "file://COPYING;md5=2d5025d4aa3495befef8f17206a5b0a1"
PR = "r0"

DEPENDS = "virtual/libusb0 pcsc-lite"
RDEPENDS_${PN} = "pcsc-lite"

SRC_URI = "http://sourceforge.net/projects/acsccid/files/acsccid/${PV}/acsccid-${PV}.tar.bz2"

SRC_URI[md5sum] = "c03fea8824766097845b3492f57b0296"
SRC_URI[sha256sum] = "fc0aa506730150721c2214ddb55903f88f0a9493ea5242a5a954377cb2baca4b"

inherit autotools

FILES_${PN} += "${libdir}/pcsc/"
FILES_${PN}-dbg += "${libdir}/pcsc/drivers/*/*/*/.debug"

ACS's Readers should be supported by the CCID lib 1.4.11, and in fact I have the model 072f: 90CC (id usb) that is regularly recognized and used.
But there are also external models aesthetically identical (except for the color or little else) which use non-CCID ACS's chipsets, such as the model 072f: 9000 (id usb).
This model is not seen by the CCID lib 1.4.11, instead using specific drivers ACSCCID also this model becomes usable.